Read and write text files in Modern Fortran

In this post, I will try to give you a quick look of the key basic concepts in modern Fortran so that we can write a simple text file using the Fortran completely. Then we will read the file using Fortran.

Basic fortran program

Let us write a program to print the area of a circle in your stdout (your terminal).

program maths
    implicit none
    real :: r, area
    real, parameter :: pi = 4.*atan(1.)
    r = 2.0
    area = pi*r**2

    print*,'The area of a circle of radius ',r,' is ',area
end program maths

Notice that I have defined a parameter using the trigonometric function atan. The good thing about Fortran is that the mathematical functions are embedded into it. (4.*atan(1.) is just a portable way to write $\pi$, since $\tan(\pi/4) = 1$.)

Let us compile this code and run it:

gfortran -o circarea circarea.f90 
./circarea

This returns:

 The area of a circle of radius    2.00000000      is    12.5663710 

The results are correct but as you may have noticed that the output is not formatted properly. So, let us fix that.

program maths
    implicit none
    real :: r, area
    real, parameter :: pi = 4.*atan(1.)
    r = 2.0
    area = pi*r**2

    write(*,1) 'The area of a circle of radius ',r,' is ',area
    1 format(A,F3.1,A,F5.2)
end program maths

This time we have used the write to output the result instead of print. You can also notice that we used the format to properly format the output:

The area of a circle of radius 2.0 is 12.57

Fortran format descriptors

Reading F5.2 as “a real number in a field 5 characters wide with 2 decimals” is the whole trick to these descriptors — the letter picks the type, the numbers pick the width and precision.

Writing to a file

Writing and later you will see that the “reading” is about using the open, close, write and read statements.

program maths
    implicit none
    real :: r, area
    real, parameter :: pi = 4.*atan(1.)
    r = 2.0
    area = pi*r**2

    ! write to ascii file
    open(unit=1,file='results.out',status='replace',form='formatted')
    write(1,11) 'The area of a circle of radius ',r,' is ',area
    11 format(A,F3.1,A,F5.2)
    close(1)
end program maths

Here write(1,11) sends the formatted line to unit 1 (attached to results.out) instead of the terminal. status='replace' overwrites the file if it already exists.

Reading from the file

program maths
    implicit none
    real :: r, area
    real, parameter :: pi = 4.*atan(1.)
    character(len=20) :: filename
    character(len = 45) :: str1
    r = 2.0
    area = pi*r**2
    filename='results.out'


    ! write to ascii file
    open(unit=1,file=filename,status='replace',form='formatted') !rewrite the file if exists
    write(1,11) 'The area of a circle of radius ',r,' is ',area
    11 format(A,F3.1,A,F5.2)
    close(1)

    ! read from ascii file
    open(unit=2,file=filename,status='old') !read from the existing file
    read(2,*) str1
    close(2)

    write(*,*) str1
end program maths

This program writes a string into a file ‘results.out’ and then read it back into a string named str1. Notice that we have defined the length of the string long enough (45 chars) to read all the string data.

Read and write the numeric data into a file

This time instead of writing it as a string, we will only write the numeric data into the file and read those data back into another variables.

program maths
    implicit none
    real :: r, area
    real :: r_rd, area_rd
    real, parameter :: pi = 4.*atan(1.)
    character(len=20) :: filename
    r = 2.0
    area = pi*r**2
    filename='results.out'


    ! write to ascii file
    open(unit=1,file=filename,status='replace',form='formatted') !rewrite the file if exists
    write(1,11) r,area
    11 format(F3.1,F5.2)
    close(1)
    
    ! read from ascii file
    open(unit=2,file=filename,status='old') !read from the existing file
    read(2,11) r_rd, area_rd
    close(2)
    
    write(*,12) r_rd, area_rd
    12 format(F3.1,2X,F5.2)
end program maths

Because we wrote the numbers with the format 11, we read them back with the same descriptor 11 — the format is the contract that keeps the written and read layouts in sync.

integer :: u, ios
open(newunit=u, file='results.out', status='old', iostat=ios)
if (ios /= 0) stop 'could not open results.out'
read(u,*) r_rd, area_rd
close(u)

Recap

• Four verbs run the show: open (attach a unit to a file), write/read (move data through the unit), close (detach).
• Formats are contracts. A descriptor like F5.2 fixes width and precision; read data back with the same format you wrote it with.
• * means “default”: write(*,*) is free-format to the terminal; swap the first * for a unit number to target a file.
• Prefer newunit= in new code. It hands you a safe unit automatically (Fortran 2008+), and pairing it with iostat= makes your I/O robust.

Where to go next

• gfortran manual (GCC): gcc.gnu.org/onlinedocs/gfortran/
• Fortran-lang learning hub: fortran-lang.org/learn/
• Formatted I/O reference (Fortran-lang): fortran-lang.org/learn/best_practices/file_io/